Question 1

After QQ[t_1] it turns out that t_1 is not an element of the ring. Why is that?

Answer

This problem is encountered mostly by users who are writing their own code. One way this can happen, in version 1.1, but not in version 0.9.95, is if t is a symbol whose value is another symbol:

    i1 : t = x

    o1 = x

    o1 : Symbol

    i2 : QQ[t_1]

    o2 = QQ [x ]
	      1

    o2 : PolynomialRing

    i3 : t_1

    o3 = x
	  1

    o3 : IndexedVariable

However, if x is used instead of t, we see our ring element:

    i4 : x_1

    o4 = x
	  1

    o4 : QQ [x ]
	      1

Internally, Macaulay 2 handles subscripted variables through "indexed variable tables":

    i5 : t

    o5 = x

    o5 : Symbol

    i6 : x

    o6 = x

    o6 : IndexedVariableTable

One solution: insert "t = value t" after creating the polynomial ring, like this:

    i1 : t = x

    o1 = x

    o1 : Symbol

    i2 : QQ[t_1]

    o2 = QQ [x ]
	      1

    o2 : PolynomialRing

    i3 : t = value t

    o3 = x

    o3 : IndexedVariableTable

    i4 : t_1

    o4 = x
	  1

    o4 : QQ [x ]
	      1

Another solution: use "value t_1" to get the ring element:

    i1 : t = x

    o1 = x

    o1 : Symbol

    i2 : QQ[t_1]

    o2 = QQ [x ]
	      1

    o2 : PolynomialRing

    i3 : t_1

    o3 = x
	  1

    o3 : IndexedVariable

    i4 : value t_1

    o4 = x
	  1

    o4 : QQ [x ]
	      1