# HH^ZZ CoherentSheaf -- cohomology of a coherent sheaf on a projective variety

## Synopsis

• Usage:
HH^i F
cohomology(i,F)
• Function: cohomology
• Inputs:
• i, an integer
• F, , on a projective variety X
• Optional inputs:
• Degree => ... (missing documentation),
• Outputs:
• , the i-th cohomology group of F as a vector space over the coefficient field of X

## Description

The command computes the i-th cohomology group of F as a vector space over the coefficient field of X. For i>0 this is currently done via local duality, while for i=0 it is computed as a limmit of Homs. Eventually there will exist an alternative option for computing sheaf cohomology via the Bernstein-Gelfand-Gelfand correspondence

As examples we compute the Picard numbers, Hodge numbers and dimension of the infinitesimal deformation spaces of various quintic hypersurfaces in projective fourspace (or their Calabi-Yau small resolutions)

We will make computations for quintics V in the family given by

x05+x15+x25+x35+x45-5λx0x1x2x3x4=0

for various values of λ. If λ is general (that is, λ not a 5-th root of unity, 0 or ), then the quintic V is smooth, so is a Calabi-Yau threefold, and in that case the Hodge numbers are as follows.

h1,1(V)=1, h2,1(V) = h1,2(V) = 101,

so the Picard group of V has rank 1 (generated by the hyperplane section) and the moduli space of V (which is unobstructed) has dimension 101:

 ```i1 : Quintic = Proj(QQ[x_0..x_4]/ideal(x_0^5+x_1^5+x_2^5+x_3^5+x_4^5-101*x_0*x_1*x_2*x_3*x_4)) o1 = Quintic o1 : ProjectiveVariety``` ```i2 : singularLocus(Quintic) /QQ[x , x , x , x , x ]\ | 0 1 2 3 4 | o2 = Proj|----------------------| \ 1 / o2 : ProjectiveVariety``` `i3 : omegaQuintic = cotangentSheaf(Quintic);` ```i4 : h11 = rank HH^1(omegaQuintic) o4 = 1``` ```i5 : h12 = rank HH^2(omegaQuintic) o5 = 101```

By Hodge duality this is h2,1. Directly h2,1 could be computed as

 ```i6 : h21 = rank HH^1(cotangentSheaf(2,Quintic)) o6 = 101```

The Hodge numbers of a (smooth) projective variety can also be computed directly using the hh command:

 ```i7 : hh^(2,1)(Quintic) o7 = 101``` ```i8 : hh^(1,1)(Quintic) o8 = 1```

Using the Hodge number we compute the topological Euler characteristic of V:

 ```i9 : euler(Quintic) o9 = -200```

When λ is a 5th root of unity the quintic V is singular. It has 125 ordinary double points (nodes), namely the orbit of the point (1:λ:λ:λ:λ) under a natural action of ℤ/53. Then V has a projective small resolution W which is a Calabi-Yau threefold (since the action of ℤ/53 is transitive on the sets of nodes of V, or for instance, just by blowing up one of the (1,5) polarized abelian surfaces V contains). Perhaps the most interesting such 3-fold is the one for the value λ=1, which is defined over and is modular (see Schoen’s work). To compute the Hodge numbers of the small resolution W of V we proceed as follows:

 ```i10 : SchoensQuintic = Proj(QQ[x_0..x_4]/ideal(x_0^5+x_1^5+x_2^5+x_3^5+x_4^5-5*x_0*x_1*x_2*x_3*x_4)) o10 = SchoensQuintic o10 : ProjectiveVariety``` ```i11 : Z = singularLocus(SchoensQuintic) o11 = Z o11 : ProjectiveVariety``` ```i12 : degree Z o12 = 125``` ```i13 : II'Z = sheaf module ideal Z o13 = image | x_3^4-x_0x_1x_2x_4 x_0x_1x_2x_3-x_4^4 x_2^4-x_0x_1x_3x_4 x_1^4-x_0x_2x_3x_4 x_0^4-x_1x_2x_3x_4 x_2^3x_3^3-x_0^2x_1^2x_4^2 x_1^3x_3^3-x_0^2x_2^2x_4^2 x_0^3x_3^3-x_1^2x_2^2x_4^2 x_1^2x_2^2x_3^2-x_0^3x_4^3 x_0^2x_2^2x_3^2-x_1^3x_4^3 x_0^2x_1^2x_3^2-x_2^3x_4^3 x_1^3x_2^3-x_0^2x_3^2x_4^2 x_0^3x_2^3-x_1^2x_3^2x_4^2 x_0^2x_1^2x_2^2-x_3^3x_4^3 x_0^3x_1^3-x_2^2x_3^2x_4^2 | 1 o13 : coherent sheaf on Proj(QQ[x , x , x , x , x ]), subsheaf of OO 0 1 2 3 4 Proj(QQ[x , x , x , x , x ]) 0 1 2 3 4```

The defect of W (that is, h1,1(W)-1) can be computed from the cohomology of the ideal sheaf of the singular locus Z of V twisted by 5 (see Werner’s thesis):

 ```i14 : defect = rank HH^1(II'Z(5)) o14 = 24``` ```i15 : h11 = defect + 1 o15 = 25```

The number h2,1(W) (the dimension of the moduli space of W) can be computed (Clemens-Griffiths, Werner) as dim H0(IZ(5))/JacobianIdeal(V)5.

 ```i16 : quinticsJac = numgens source basis(5,ideal Z) o16 = 25``` ```i17 : h21 = rank HH^0(II'Z(5)) - quinticsJac o17 = 0```

In other words W is rigid. It has the following topological Euler characteristic.

 ```i18 : chiW = euler(Quintic)+2*degree(Z) o18 = 50```